build.gradle

apply plugin: 'com.android.library'
apply plugin: 'witness'

android {
    compileSdkVersion Integer.parseInt(project.ANDROID_BUILD_SDK_VERSION)
    buildToolsVersion project.ANDROID_BUILD_TOOLS_VERSION

    defaultConfig {
        minSdkVersion 9
        targetSdkVersion Integer.parseInt(project.ANDROID_BUILD_TARGET_SDK_VERSION)
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }
    lintOptions {
        abortOnError false
    }
}

dependencies {
    compile project(path: ':routerjars', configuration: 'client')
    compile 'com.android.support:support-v4:21.0.2'
}

dependencyVerification {
    verify = [
            'com.android.support:support-v4:126a4c291f41f75f3fff4968e9d397bc8454cdff4d8f994cbe0524e3bad76e72',
    ]
}

android.libraryVariants.all { variant ->
    // Copy I2P client JARs into AAR
    def copyClientLibsTask = tasks.create(name: "copy${variant.name.capitalize()}ClientLibs", type: Copy) {
        from project(':routerjars').configurations.client.allArtifacts.collect { artifact ->
            artifact.file
        }
        destinationDir file("${buildDir}/intermediates/bundles/${variant.dirName}/libs")
    }

    // Hook the copy task into the build
    variant.processJavaResources.dependsOn copyClientLibsTask
    copyClientLibsTask.mustRunAfter ':routerjars:buildClient'
}

apply from: "${project.rootDir}/gradle/maven-push.gradle"

// Remove routerjars from dependencies
afterEvaluate { project ->
    def deployer = uploadArchives.repositories.mavenDeployer
    deployer*.pom*.whenConfigured { pom ->
        pom.setDependencies(pom.dependencies.collect { dep ->
            if (dep.groupId != 'i2p.android.base' && dep.artifactId != 'routerjars')
                dep
        })
    }
}